1 | /* Copyright (C) 2001-2020 Free Software Foundation, Inc. |
2 | This file is part of the GNU C Library. |
3 | |
4 | The GNU C Library is free software; you can redistribute it and/or |
5 | modify it under the terms of the GNU Lesser General Public |
6 | License as published by the Free Software Foundation; either |
7 | version 2.1 of the License, or (at your option) any later version. |
8 | |
9 | The GNU C Library is distributed in the hope that it will be useful, |
10 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
11 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
12 | Lesser General Public License for more details. |
13 | |
14 | You should have received a copy of the GNU Lesser General Public |
15 | License along with the GNU C Library; if not, see |
16 | <https://www.gnu.org/licenses/>. */ |
17 | |
18 | #include <sysdep.h> |
19 | #define _ERRNO_H 1 |
20 | #include <bits/errno.h> |
21 | #include <tcb-offsets.h> |
22 | |
23 | #if SHSTK_ENABLED |
24 | /* The shadow stack prevents us from pushing the saved return PC onto |
25 | the stack and returning normally. Instead we pop the shadow stack |
26 | and return directly. This is the safest way to return and ensures |
27 | any stack manipulations done by the vfork'd child doesn't cause the |
28 | parent to terminate when CET is enabled. */ |
29 | # undef SYSCALL_ERROR_HANDLER |
30 | # define SYSCALL_ERROR_HANDLER \ |
31 | 0: \ |
32 | SYSCALL_SET_ERRNO; \ |
33 | or $-1, %RAX_LP; \ |
34 | jmp 1b; |
35 | # undef SYSCALL_ERROR_LABEL |
36 | # define SYSCALL_ERROR_LABEL 0f |
37 | #endif |
38 | |
39 | /* Clone the calling process, but without copying the whole address space. |
40 | The calling process is suspended until the new process exits or is |
41 | replaced by a call to `execve'. Return -1 for errors, 0 to the new process, |
42 | and the process ID of the new process to the old process. */ |
43 | |
44 | ENTRY (__vfork) |
45 | |
46 | /* Pop the return PC value into RDI. We need a register that |
47 | is preserved by the syscall and that we're allowed to destroy. */ |
48 | popq %rdi |
49 | cfi_adjust_cfa_offset(-8) |
50 | cfi_register(%rip, %rdi) |
51 | |
52 | /* Stuff the syscall number in RAX and enter into the kernel. */ |
53 | movl $SYS_ify (vfork), %eax |
54 | syscall |
55 | |
56 | #if !SHSTK_ENABLED |
57 | /* Push back the return PC. */ |
58 | pushq %rdi |
59 | cfi_adjust_cfa_offset(8) |
60 | #endif |
61 | |
62 | cmpl $-4095, %eax |
63 | jae SYSCALL_ERROR_LABEL /* Branch forward if it failed. */ |
64 | |
65 | #if SHSTK_ENABLED |
66 | 1: |
67 | /* Check if shadow stack is in use. */ |
68 | xorl %esi, %esi |
69 | rdsspq %rsi |
70 | testq %rsi, %rsi |
71 | /* Normal return if shadow stack isn't in use. */ |
72 | je L(no_shstk) |
73 | |
74 | /* Pop return address from shadow stack and jump back to caller |
75 | directly. */ |
76 | movl $1, %esi |
77 | incsspq %rsi |
78 | jmp *%rdi |
79 | |
80 | L(no_shstk): |
81 | /* Push back the return PC. */ |
82 | pushq %rdi |
83 | cfi_adjust_cfa_offset(8) |
84 | #endif |
85 | |
86 | /* Normal return. */ |
87 | ret |
88 | |
89 | PSEUDO_END (__vfork) |
90 | libc_hidden_def (__vfork) |
91 | |
92 | weak_alias (__vfork, vfork) |
93 | strong_alias (__vfork, __libc_vfork) |
94 | |